home *** CD-ROM | disk | FTP | other *** search
/ FM Towns: Free Software Collection 9 / FM Towns Free Software Collection 9.iso / t_os / joke / yen / yen.bas < prev    next >
BASIC Source File  |  1994-11-16  |  4KB  |  116 lines
  1. 100 '======================================================
  2. 110 '                     いくらでＳＨＯＷ
  3. 120 '   by 前工 電子研究部     （12ドット表示用）
  4. 130 '======================================================
  5. 140 '
  6. 150 CLEAR:DEFINT A-Z:RANDOMIZE TIME
  7. 160 MOUSE 0:ON MOUSE(4) GOSUB *END
  8. 170 '
  9. 180 OO=(INT((INT((50+7)/8)*50*5+2-1)/2))
  10. 190 DIM OKANE(OO*6)
  11. 200 SCREEN 1,,0
  12. 210 LOAD@ "YEN.TIF"
  13. 220 FOR I=0 TO 5
  14. 230   GET@A (0,I*50)-(49,I*50+49),OKANE,I*OO
  15. 240 NEXT
  16. 250 '
  17. 260 SCREEN 0
  18. 270 SCREEN@ 0:WINDOW (0,0)-(639,479):VIEW (0,0)-(639,479):CLS
  19. 280 '
  20. 290 DIM IKURA(10000),DESITA(8000),MARU(12000),BATU(12000)
  21. 300 LOAD@ "IKURA.SND",IKURA:LOAD@ "ENDESITA.SND",DESITA
  22. 310 LOAD@ "MARU.SND",MARU:LOAD@ "BATU.SND",BATU
  23. 320 '
  24. 330 DIM YEN1(8500),YEN5(11000),YEN10(16000),YEN50(17000),YEN100(26000),YEN500(7000)
  25. 340 LOAD@ "YEN1.SND",YEN1:LOAD@ "YEN5.SND",YEN5:LOAD@ "YEN10.SND",YEN10
  26. 350 LOAD@ "YEN50.SND",YEN50:LOAD@ "YEN100.SND",YEN100:LOAD@ "YEN500.SND",YEN500
  27. 360 '
  28. 370 DIM EN1(2300),EN5(1500),EN10(8000),EN50(5000),EN100(4000),EN500(6000)
  29. 380 LOAD@ "1YEN.SND",EN1:LOAD@ "5YEN.SND",EN5:LOAD@ "10YEN.SND",EN10
  30. 390 LOAD@ "50YEN.SND",EN50:LOAD@ "100YEN.SND",EN100:LOAD@ "500YEN.SND",EN500
  31. 400 '
  32. 410 GOSUB *TITLE
  33. 420 Y_OF=50:X_OF=250:DEF PEN 0,3:CONSOLE 2,21
  34. 430 FOR I=0 TO 5
  35. 440   PUT@A (X_OF,Y_OF+I*50)-(X_OF+49,Y_OF+I*50+49),OKANE,PSET,1,1,,OO*I
  36. 450 NEXT
  37. 460 '
  38. 470 MOUSE 1,,,1:MOUSE 4,X_OF,Y_OF,X_OF+49,Y_OF+50*6-1
  39. 480 SYMBOL (400,70),"右クリックで終了",1,1,6:MOUSE (4) ON
  40. 490 '
  41. 500 *MAIN '--------------------------------------------------
  42. 510 PRINT "いくらでしょう？"
  43. 520 LINE (350,250)-(640,480),PSET,0,BF:SYMBOL (350,250),"？",15,13,7
  44. 530 PCMPLAY IKURA:WAIT 110
  45. 540 R=INT (RND(1)*6)
  46. 550 IF R=0 THEN PCMPLAY YEN1:Q$="一"
  47. 560 IF R=1 THEN PCMPLAY YEN5:Q$="五"
  48. 570 IF R=2 THEN PCMPLAY YEN10:Q$="十"
  49. 580 IF R=3 THEN PCMPLAY YEN50:Q$="五十"
  50. 590 IF R=4 THEN PCMPLAY YEN100:Q$="百"
  51. 600 IF R=5 THEN PCMPLAY YEN500:Q$="五百"
  52. 610 WAIT 100
  53. 620 GOSUB *INPUT
  54. 630 GOSUB *CHECK
  55. 640 IF R=0 THEN PCMPLAY EN1
  56. 650 IF R=1 THEN PCMPLAY EN5
  57. 660 IF R=2 THEN PCMPLAY EN10
  58. 670 IF R=3 THEN PCMPLAY EN50
  59. 680 IF R=4 THEN PCMPLAY EN100
  60. 690 IF R=5 THEN PCMPLAY EN500
  61. 700 WAIT 50
  62. 710 PRINT Q$;"円でした。":PRINT
  63. 720 PCMPLAY DESITA
  64. 730 WAIT 160:N=N+1:MOUSE (4) ON
  65. 740 GOTO *MAIN
  66. 750 '
  67. 760 *INPUT '--------------------------------------------------
  68. 770 COIN=( MOUSE(1)-Y_OF )\ 50
  69. 780 LINE (X_OF,Y_OF+COIN*50)-(X_OF+49,Y_OF+COIN*50+49),XOR,4,B
  70. 790 WHILE MOUSE(2,0)=0
  71. 800   COIN_A=COIN:COIN=( MOUSE(1)-Y_OF )\ 50
  72. 810   IF COIN<>COIN_A THEN
  73. 820     LINE (X_OF,Y_OF+COIN_A*50)-(X_OF+49,Y_OF+COIN_A*50+49),XOR,4,B
  74. 830     LINE (X_OF,Y_OF+COIN*50)-(X_OF+49,Y_OF+COIN*50+49),XOR,4,B
  75. 840   ENDIF
  76. 850 WEND
  77. 860 LINE (X_OF,Y_OF+COIN*50)-(X_OF+49,Y_OF+COIN*50+49),XOR,4,B
  78. 870 MOUSE (4) OFF
  79. 880 RETURN
  80. 890 '
  81. 900 *CHECK '--------------------------------------------------
  82. 910 IF R=COIN THEN
  83. 920   PRINT "正解":P=P+1:PCMPLAY MARU
  84. 930 ELSE
  85. 940   PRINT "はずれ":PCMPLAY BATU
  86. 950 ENDIF
  87. 960 FOR I=1 TO 28
  88. 970     PUT@A (350,250)-(350+49,250+49),OKANE,PSET,5,5,,OO*R+I
  89. 980 NEXT I
  90. 990 WAIT 100
  91. 1000 RETURN
  92. 1010 '
  93. 1020 *END '----------------------------------------------------
  94. 1030 MOUSE 5:E=1:CLS 4:GOSUB *TITLE
  95. 1040 WAIT 200
  96. 1050 END
  97. 1060 '
  98. 1070 *TITLE '====================================================
  99. 1080 FOR I=1 TO 1000
  100. 1090   X=INT(RND(1)*590) :Y=INT(RND(1)*430)
  101. 1100   PUT@A (X,Y)-(X+49,Y+49),OKANE,MATTE,1,1,0,OO*INT(RND(1)*6)
  102. 1110 NEXT
  103. 1120 '
  104. 1130 SYMBOL (50,80),"いくらでＳＨＯＷ",4,6,5,,PSET,13
  105. 1140 IF E=1 THEN
  106. 1150   IF N=0 THEN P=0 : N=1  '一つも問題に答えなかった時
  107. 1160   SYMBOL (50,190),"   正答率"+STR$(INT(P/N*100))+" ％",4,6,%9,,PSET,13
  108. 1170   SYMBOL (50,310),"    終了",6,6,5,,PSET,13
  109. 1180 ELSE
  110. 1190   SYMBOL (50,310),"ＨＩＴ 左クリック",4,4,%9,,PSET,13
  111. 1200   WHILE MOUSE (2,0)=0 :WEND
  112. 1210   CLS
  113. 1220   WAIT 100
  114. 1230 ENDIF
  115. 1240 RETURN
  116.